blob: ef30bd20a51b65a53698c182cbddf3acdd6fd095 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
QT += core network
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets x11extras multimedia
TARGET=LuminaUtils
isEmpty(PREFIX) {
PREFIX = /usr/local
}
system(./make-global-h.sh $$PREFIX)
isEmpty(LIBPREFIX) {
LIBPREFIX = $$PREFIX/lib
}
target.path = $$LIBPREFIX
DESTDIR= $$_PRO_FILE_PWD_/
TEMPLATE = lib
LANGUAGE = C++
VERSION = 1
HEADERS += LuminaXDG.h \
LuminaUtils.h \
LuminaX11.h \
LuminaThemes.h \
LuminaOS.h \
LuminaSingleApplication.h
SOURCES += LuminaXDG.cpp \
LuminaUtils.cpp \
LuminaX11.cpp \
LuminaThemes.cpp \
LuminaSingleApplication.cpp \
LuminaOS-FreeBSD.cpp \
LuminaOS-DragonFly.cpp \
LuminaOS-OpenBSD.cpp \
LuminaOS-kFreeBSD.cpp
# new OS support can be added here
# check linux distribution and use specific
# LuminaOS support functions (or fall back to
# generic one
exists(/bin/lsb_release){
LINUX_DISTRIBUTION = $$system(lsb_release -si)
}
equals(LINUX_DISTRIBUTION, "Debian"): {
SOURCES += LuminaOS-Debian.cpp
} else {
SOURCES += LuminaOS-Linux.cpp
}
INCLUDEPATH += $$PREFIX/include
LIBS += -lX11 -lXrender -lXcomposite -lxcb -lxcb-ewmh -lxcb-icccm -lxcb-image -lxcb-composite -lxcb-damage
include.path=$$PREFIX/include/
include.files=LuminaXDG.h \
LuminaUtils.h \
LuminaX11.h \
LuminaThemes.h \
LuminaOS.h \
LuminaSingleApplication.h
colors.path=$$PREFIX/share/Lumina-DE/colors/
colors.files=colors/Lumina-Red.qss.colors \
colors/Lumina-Green.qss.colors \
colors/Lumina-Purple.qss.colors \
colors/Lumina-Gold.qss.colors \
colors/Lumina-Glass.qss.colors \
colors/PCBSD10-Default.qss.colors
themes.path=$$PREFIX/share/Lumina-DE/themes/
themes.files=themes/Lumina-default.qss.template \
themes/None.qss.template
INSTALLS += target include colors themes
QMAKE_LIBDIR = $$LIBPREFIX/qt5 $$LIBPREFIX
|
