build.gradle.kts


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

import org.gradle.api.tasks.testing.logging.TestLogEvent.*

plugins {
    val kotlinVersion = "1.3.72"
    kotlin("js") version kotlinVersion apply false
    kotlin("jvm") version kotlinVersion apply false
    kotlin("multiplatform") version kotlinVersion apply false
    kotlin("plugin.spring") version kotlinVersion apply false
    id("org.jetbrains.kotlin.plugin.serialization") version kotlinVersion apply false
    id("org.jlleitschuh.gradle.ktlint") version "9.1.1" apply false
}

subprojects {
    repositories {
        jcenter()
    }

    val compilerArgs = listOf("-Xopt-in=kotlin.RequiresOptIn")
    tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile> {
        kotlinOptions.jvmTarget = "1.8"
        kotlinOptions.freeCompilerArgs += compilerArgs
    }

    tasks.withType<org.jetbrains.kotlin.gradle.tasks.Kotlin2JsCompile> {
        kotlinOptions.freeCompilerArgs = compilerArgs
    }

    tasks.withType<AbstractTestTask> {
        testLogging {
            events(FAILED, STANDARD_ERROR)
            exceptionFormat = org.gradle.api.tasks.testing.logging.TestExceptionFormat.FULL
            showStackTraces = true
        }
    }

    afterEvaluate {
        // The import ordering expected by ktlint is alphabetical, which doesn't match IDEA's formatter.
        // Since it is not configurable, we have to disable the rule.
        // https://github.com/pinterest/ktlint/issues/527
        extensions.configure<org.jlleitschuh.gradle.ktlint.KtlintExtension> {
            disabledRules.set(setOf("import-ordering", "no-wildcard-imports"))
        }
    }
}