From 472d7c466d33bd1fe4cd293b354e52bf16384520 Mon Sep 17 00:00:00 2001
From: Gordon Norman Squash <gordsqsh@protonmail.com>
Date: Tue, 10 Sep 2024 01:28:29 -0400
Subject: Initial commit

This is where I have started tracking development with Git.  I declare this
as version 0.89.
---
 meson.build | 74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 meson.build

(limited to 'meson.build')

diff --git a/meson.build b/meson.build
new file mode 100644
index 0000000..7c41125
--- /dev/null
+++ b/meson.build
@@ -0,0 +1,74 @@
+project ('gtk3-classic-module', 'c',
+	version : '0.89',
+	default_options : [
+		'buildtype=release',
+		'optimization=2',
+		'prefix=/usr',
+		'strip=true',
+		'warning_level=3'
+	],
+	license: 'LGPLv3+')
+
+
+gtk_version_required = '>= 3.24.0'
+gtk_dep = dependency ('gtk+-3.0',
+	version: gtk_version_required)
+gtk_unix_print_dep = dependency ('gtk+-unix-print-3.0',
+	version: gtk_version_required)
+# For glib-compile-schemas
+gnome = import ('gnome')
+
+
+gtk_libdir = gtk_dep.get_variable (
+	pkgconfig: 'libdir',
+	internal: 'libdir',
+	default_value: get_option ('libdir'))
+
+gtk_sysconfdir = gtk_dep.get_variable (
+	pkgconfig: 'sysconfdir',
+	internal: 'sysconfdir',
+	default_value: get_option ('sysconfdir'))
+
+gtk_datadir = gtk_dep.get_variable (
+	pkgconfig: 'datadir',
+	internal: 'datadir',
+	default_value: get_option ('datadir'))
+
+
+modules_subdir = 'gtk-3.0/modules'
+modules_install_dir = join_paths (gtk_libdir, modules_subdir)
+
+settings_subdir = 'gtk-3.0'
+settings_install_dir = join_paths (gtk_sysconfdir, settings_subdir)
+
+schemas_subdir = 'glib-2.0/schemas'
+schemas_install_dir = join_paths (gtk_datadir, schemas_subdir)
+
+
+include_dir = include_directories ('include')
+
+
+shared_module ('gtk3-classic-module',
+	sources: [
+		'main.c',
+		'patches/button-menu-icons.c',
+		'patches/dialogs.c',
+		'patches/icon-sizes.c',
+		'patches/no-emojis.c',
+		'patches/persistent-mnemonics.c',
+		'patches/smaller-widgets.c'
+	],
+	include_directories: [ include_dir ],
+	dependencies: [ gtk_dep, gtk_unix_print_dep ],
+	install_dir: modules_install_dir,
+	install: true
+)
+
+
+install_data ('data/settings.ini',
+	install_dir: settings_install_dir)
+
+schema_file = 'data/00_gtk3-classic-module.gschema.override'
+install_data (schema_file,
+	install_dir: schemas_install_dir)
+gnome.post_install (glib_compile_schemas: true)
-- 
cgit